@ > Home > Inhalt > Kombinationen von Datenpaaren auflisten Excel 97+

Aufgabe: 

Die formelseitige Darstellung von (allgemein N^2) Kombinationen mit Wiederholung (auch von sich selbst) ist leicht lösbar: 

D1: =INDEX(x;REST(ZEILE()-1;N)+1)
E1: =INDEX(x;ZEILE()/N+1-1%%%)

mit x: =A1:A5 und N: =ANZAHL($A:$A)

Wie aber erreicht man eine Liste ohne Wiederholungen (mit allgemein N*(N-1)/2 Einträgen), dargestellt in B:C? 

        A   B   C   D   E   
    1   1   4   5   1   1
    2   2   3   5   2   1
    3   3   3   4   3   1
    4   4   2   5   4   1
    5   5   2   4   5   1
    6       2   3   1   2
    7       1   5   2   2
    8       1   4   3   2
    9       1   3   4   2
   10       1   2   5   2
   11               1   3

Lösung: 

B1: =INDEX(x;N-RUNDEN((2*ZEILE())^0,5;))
C1: =INDEX(x;N)
C2: =INDEX(x;WENN(B2<B1;N;C1-1))

(bis auf C1 jeweils runterzukopieren)

Um die Formeln C:C auch als Matrixformelbestandteil funktionierend zu erhalten, verwende man statt dessen herunterkopiert

C1: =INDEX(x;N+1-RUNDEN(((2*ZEILE())^0,5-RUNDEN((2*ZEILE())^0,5;)+0,5)/((2*ZEILE())^0,5-(2*(ZEILE()-1))^0,5);))

Erklärung: Die kürzere Formel in C2 benötigt Vorgänger und ist damit in Matrixformeln nicht geeignet. Auch muss A:A dafür sortiert sein. Die längere Formel ermittelt hingegen die richtigen Werte durch Berechnung. Eine Sortierung von A:A ist nicht nötig.